post deleted

Hello

I was wanting to ask the forum on how you guys prefer to organize your code, especially on larger projects. I've posted a few of my projects on here and people had trouble getting them to work due to the way I structure my code. I want to make it as easy as possible to share across platforms, since I'm a Linux guy. 

• Do you prefer a large monolithic source file, or it broken up into libraries?
  
• If you use "libraries", do you keep them together with your original project, or do you separate them for reuse on other projects?
  
• Do you put the executable in the QB folder or in the source folder?
  
• How do you handle assets in regards to your file structure, so that it is easier to share?
  

The discussion about the PLAY command prompted me to create this little demo of using the features it provides.
Most, if not all of it will be common knowledge, I guess, but I find it useful to clarify my thinking about some of the
less-common ones.

Wiki help: https://qb64phoenix.com/qb64wiki/index.php/HYPOT

What wiki doesn't say is that this function contains a very useful Distance Formula between two points on a 2D plane.

Distance between two points (x1, y1) and (x2, y2) ( a diagram would be helpful here, sorry I am going to attempt in words only).

Distance = SQR((x1 - x2) ^ 2 + (y1 - y2) ^ 2)

(x1 - x2) represents the length of one leg of a right triangle
(y1 - y2) represents the other leg

So by the Pythagorean Theorem the Hypotenuse (length) equals the SQR of the square (^2) of both sides.
ie Distance = _Hypot(x1 - x2), (y1 - y2))

The point is we have a Distance formula built-into the QB64 Functions and don't need to carry a Distance Function from our Toolbox of Subs and Functions.

I bring this up because I am kicking myself for missing it yesterday in the enRitchied Code for Missile Command here:
https://staging.qb64phoenix.com/showthre...8#pid17088

I shoulda, coulda, done it better like this:

Option _Explicit '                          Get into this habit and save yourself grief from Typos



_Title "Missile Command EnRitchied" '    another b+ mod 2023-06-24, replace distance with _Hypot.

'                                  I probably picked up this game at the JB forum some years ago.



'    Get Constants, Shared Variables and Arrays() declared. These Will Start with Capital Letters.

'        Get Main module variables and arrays declared with starting lower case letters for local.

'        This is what Option _Explicit helps, by forcing us to at least declare these before use.

'      While declaring, telling QB64 the Type we want to use, we can also give brief description.





Const ScreenWidth = 800, ScreenHeight = 600 '                    for our custom screen dimensions

Dim As Integer bombX, bombY '                          incoming bomb screen position to shoot down

Dim As Single bombDX, bombDY '                  DX and DY mean change in X position and Y position

Dim As Integer missileX, missileY '                                              missile position

Dim As Single missileDX, missileDY '                            change X and Y of Missile position

Dim As Integer hits, misses '                                                score hits and misses

Dim As Integer mouseDistanceX, mouseDistanceY '      for calculations of missile DX, DY direction

Dim As Single distance '                                                                    ditto

Dim As Integer radius '                                      drawing hits with target like circles

Dim As Integer boolean '                        to shorten the code line with a bunch of OR tests



Screen _NewImage(ScreenWidth, ScreenHeight, 32) ' sets up a graphics screen with custom dimensions

'                                          the 32 is for _RGB32(red, green, blue, alpha) coloring.

'

_ScreenMove 250, 60 '            this centers screen in my laptop, you may need different numbers



InitializeForRound: '                            reset game and start a round with a bomb falling

Cls

bombX = Rnd * ScreenWidth '                                starts bomb somewhere across the screen

bombY = 0 '                                                          starts bomb at top of screen

bombDX = Rnd * 6 - 3 '                                  pick rnd dx = change in x between -3 and 3

bombDY = Rnd * 3 + 3 '                pick rnd dy = change in y between 3 and 6,  > 0 for falling

missileX = ScreenWidth / 2 '                                  missile base at middle across screen

missileY = ScreenHeight - 4 '  missile launch point at missile base is nearly at bottom of screen

missileDX = 0 '                          missile is not moving awaiting mouse click for direction

missileDY = 0 '                                                                              ditto

distance = 0 '                                            distance of mouse click to missile base



Do

    'what's the score?

    _Title "Click mouse to intersect incoming  Hits:" + Str$(hits) + ", misses:" + Str$(misses)

    _PrintString (400, 594), "^" '                                draw missle base = launch point

    While _MouseInput: Wend '                                            poll mouse to get update

    If _MouseButton(1) Then '              the mouse was clicked calc the angle from missile base

        mouseDistanceX = _MouseX - missileX

        mouseDistanceY = _MouseY - missileY

        distance = (mouseDistanceX ^ 2 + mouseDistanceY ^ 2) ^ .5

        missileDX = 5 * mouseDistanceX / distance

        missileDY = 5 * mouseDistanceY / distance

    End If



    missileX = missileX + missileDX '                                      update missile position

    missileY = missileY + missileDY '                                                        ditto

    bombX = bombX + bombDX '                                                  update bomb position

    bombY = bombY + bombDY '                                                                ditto



    '                    I am about to use a boolean variable to shorten a very long IF code line

    '                                boolean is either 0 or -1 when next 2 statements are execued

    '                                            -1/0 or True/False is everything still in screen?

    boolean = missileX < 0 Or missileY < 0 Or bombX < 0 Or bombY < 0

    boolean = boolean Or missileX > ScreenWidth Or bombX > ScreenWidth Or bombY > ScreenHeight

    If boolean Then ' done with this boolean

        '  reuse boolean to shorten another long code line checking if bomb and missile in screen

        boolean = bombY > ScreenHeight Or missileX < 0 Or missileY < 0 Or missileX > ScreenWidth

        If boolean Then misses = misses + 1

        GoTo InitializeForRound

    End If



    '    if the distance between missle and bomb < 20 pixels then the missile got the bomb, a hit

    'If ((missileX - bombX) ^ 2 + (missileY - bombY) ^ 2) ^ .5 < 20 Then '  show a strike as target



    'rewrite the above line using _Hypot() which is hidden distance forumla

    If _Hypot(missileX - bombX, missileY - bombY) < 20 Then





        For radius = 1 To 20 Step 4 '                        draw concetric circles to show strike

            Circle ((missileX + bombX) / 2, (missileY + bombY) / 2), radius

            _Limit 60

        Next

        hits = hits + 1 '                                                    add hit to hits score

        GoTo InitializeForRound

    Else

        PSet (missileX, missileY), &HFFFFFF00 '                            draw your missle yellow

        PSet (bombX, bombY), &HFF0000FF '                                          draw bomb blue

    End If

    _Limit 20

Loop

QB64 Phoenix Edition Summer 2023 Banner Contest

Please vote for your choice in the banner contest!
*edit* @bplus entry was updated for final version. @JRace submission was added. @dbox last submission was kept all others removed, and votes moved to @dbox last submission if they existed for other submissions.

*subtle drum-roll*

And the entries for the QB64 PE Summer 2023 Banner Contest are...

*cymbals*

1. @bplus - Summer Fun Edition


2. @TerryRitchie - Summer Edition (made with QB64PE source)


3. @JRace - Summer Edition modification on @TerryRitchie


4. @SMcNeill - Summer Edition Phoenix (get well soon Steve)


5. @dbox - Angry Birds - Sun, Sand, and Syntax Errors


---

The winner of this poll will have their work featured on the forum on all themes!

Good luck to all the contestants and please place your votes now.

We will accept voting until July 1st at which time the winner will be chosen based on the number of votes their submission has received!

---

Feel free to talk and socialize in this thread and to congratulate the winner when the contest is over!

A few done so far related to BAM enhancements in the works:

The All Syntax Diagrams page.

I was supposed to go further with my "musak" creators for PLAY, but decided this time to provide something different. This was an idea I already revealed. I would like to thank Mr.Why from the old forum, from the one Galleon was administrator, for inspiring me many years ago into stuff like this.

This is a program that does silly "space music". It creates an empty QB64 screenie because I'm not a good artist, I focused only on the sound. Press [ESC] to quit. Don't panic if it doesn't leave straight away, give it 3 seconds at least until the sound dies away.

This purposely does 440 samples to generate sound or not, then checks if it could create a new voice. Usually the "space dot" is created which is very brief. At other times, it could create a whitenoise wash (would like to be able to produce a brown or pink noise here instead), or it could create a "space rumble" although not a very good one maybe because the pitches are a bit too high.

There are two constants that could be adjusted near the top of the program. I don't recommend changing "NUMNOISE" to a value near "NUMSOUNDS", otherwise the program will choose the "deep" noises more often than the "dots".

'by mnrvovrfc 23-June-2023

OPTION _EXPLICIT



CONST NUMSOUNDS = 50, NUMNOISE = 10



'active = the voice is active (1=dot random sine; 2=whitenoise; 3=deep space "rumble" sine)

'enable = the voice is being sent to audio output

'  (after amplitude envelope goes through attack and release, this is set to zero and "hold" is updated)

'freq = voice frequency, could be changed by "tun"

'acount = amplitude attack increment in degrees

'rcount = amplitude release increment in degrees

'  these two operate over half a sinewave to do an amplitude envelope

'a = degrees for amplitude envelope

't = time according to computation in QB64 Wiki example for _SNDRAW

'vol = volume adjustment for the voice

'tun = small change in frequency only for active=3

'hold = after the voice stops being enabled, how long to hold until making this voice available again

'  this is a count in samples so depends on sampling rate

'  I assumed 44100Hz so this could go for as long as four seconds but not less than 1/4-second

'  this is to prevent the sound scape from being too thick

TYPE spacemtype

    AS _BYTE active, enable

    AS SINGLE freq, acount, rcount, tun, vol, a

    AS LONG t, hold

END TYPE



DIM SHARED s(1 TO NUMSOUNDS) AS spacemtype

DIM AS INTEGER kount, i, j, o

DIM AS SINGLE twopi, ao, ag, samprate



twopi = _PI * 2

samprate = _SNDRATE



RANDOMIZE TIMER

_TITLE "Fake Cosmos!"



DO

    IF kount < NUMNOISE THEN

        kount = kount + 1

        createnewsound Rand(2, 3)

    ELSE

        createnewsound 1

    END IF

    FOR o = 1 TO 440

        ag = 0

        FOR i = 1 TO NUMSOUNDS

            IF s(i).active THEN

                s(i).t = s(i).t + 1

                IF s(i).a > 90 THEN

                    s(i).a = s(i).a + s(i).rcount

                ELSE

                    s(i).a = s(i).a + s(i).acount

                END IF

                IF s(i).a > 180 THEN

                    s(i).enable = 0

                    s(i).hold = s(i).hold - 1

                    IF s(i).hold < 1 THEN

                        IF s(i).active > 1 THEN kount = kount - 1

                        s(i).active = 0

                        EXIT FOR

                    END IF

                END IF

                IF s(i).enable THEN

                    IF s(i).freq THEN

                        ao = s(i).freq

                        IF s(i).tun THEN s(i).freq = s(i).freq + s(i).tun

                    ELSE

                        ao = Random1(7900) + 100

                    END IF

                    ao = ao / samprate

                    ao = (SIN(ao * twopi * s(i).t) * s(i).vol * SIN(_D2R(s(i).a)))

                    ag = ag + ao

                END IF

            END IF

        NEXT 'i

        IF ag < -1.0 THEN ag = -1.0

        IF ag > 1.0 THEN ag = 1.0

        _SNDRAW ag

    NEXT 'o

    DO WHILE _SNDRAWLEN > 3

        _LIMIT 100

        IF _KEYDOWN(27) THEN EXIT DO

    LOOP

LOOP UNTIL _KEYDOWN(27)



DO WHILE _SNDRAWLEN

    _LIMIT 100

LOOP

SYSTEM





SUB createnewsound (which)

    DIM AS INTEGER i, j

    FOR i = 1 TO NUMSOUNDS

        IF s(i).active = 0 THEN j = i: EXIT FOR

    NEXT i

    IF j = 0 THEN EXIT SUB

    s(j).active = which

    s(j).enable = 1

    s(j).a = 0

    IF which = 1 THEN

        s(j).freq = Rand(5, 80) * 50

        s(j).acount = Rand(30, 100) / 100

        s(j).rcount = Rand(30, 100) / 100

        s(j).tun = 0

        s(j).vol = Rand(10, 50) / 100

        s(j).hold = 0

    ELSEIF which = 2 THEN

        s(j).freq = 0

        s(j).tun = 0

        s(j).acount = Rand(7, 50) / 10000

        s(j).rcount = Rand(25, 100) / 2000

        s(j).vol = 0.0625

        s(j).hold = Rand(11025, 88200)

    ELSEIF which = 3 THEN

        s(j).freq = Rand(80, 240)

        s(j).acount = Rand(25, 100) / 2000

        s(j).rcount = Rand(7, 50) / 10000

        s(j).vol = 0.125

        s(j).hold = Rand(22050, 176400)

        IF Random1(3) = 1 THEN

            IF s(j).freq > 160 THEN s(j).tun = -1 ELSE s(j).tun = 1

            s(j).tun = s(j).tun * Random1(100) / 1E+6

        ELSE

            s(j).tun = 0

        END IF

    END IF

END SUB





FUNCTION Rand& (fromval&, toval&)

    DIM sg%, f&, t&

    IF fromval& = toval& THEN

        Rand& = fromval&

        EXIT FUNCTION

    END IF

    f& = fromval&

    t& = toval&

    IF (f& < 0) AND (t& < 0) THEN

        sg% = -1

        f& = f& * -1

        t& = t& * -1

    ELSE

        sg% = 1

    END IF

    IF f& > t& THEN SWAP f&, t&

    Rand& = INT(RND * (t& - f& + 1) + f&) * sg%

END FUNCTION



FUNCTION Random1& (maxvaluu&)

    DIM sg%

    sg% = SGN(maxvaluu&)

    IF sg% = 0 THEN

        Random1& = 0

    ELSE

        IF sg% = -1 THEN maxvaluu& = maxvaluu& * -1

        Random1& = INT(RND * maxvaluu& + 1) * sg%

    END IF

END FUNCTION

Is the problem with my scanning/conversion routine or how DRAW actually draws?
(The draw statements it produces could be optimized to be briefer, I just haven't done that here. I want to get the scanning and rendered correctly first).

This is a QB64-PE binding library for the popular raylib library. raylib is a simple and easy-to-use library to enjoy videogames programming.

a740g/raylib-64: QB64-PE bindings for raylib (a simple and easy-to-use library to learn videogames programming) (github.com)

https://github.com/a740g/raylib-64/archi...master.zip

Note that this is still a work-in-progress. However, many things already work. Please read the FAQ and notes in README.md before using the library.

Open any feedback / issue here: Issues · a740g/raylib-64 (github.com)

Pull Requests are welcome. 

Cheers!

Update: Finished bindings for 2D physics library Physac.