'Anti-Primes: Calculate first 45 anti-primes

'date of code: 06 JUL 2023

'Space Ghost (modified QBasic 4.5 from Rosetta Code)



'HOUSEKEEPING -----------------------------------

$CONSOLE:ONLY

OPTION _EXPLICIT

CLS



'VARIABLE DECLARATIONS  -------------------------

DIM t AS DOUBLE

DIM tmp AS STRING

DIM AS INTEGER MaxAntiPrime, AntiPrimeCount

DIM AS LONG MaxDivisors, Divisors, n



'MAIN BLOCK  ------------------------------------

t = TIMER(0.001)



MaxAntiPrime = 45

n = 0

MaxDivisors = 0

AntiPrimeCount = 0



PRINT "The first 45 anti-primes are:"

PRINT



WHILE AntiPrimeCount < MaxAntiPrime

    n = n + 1

    Divisors = DivisorCount(n)

    IF Divisors > MaxDivisors THEN

        PRINT n;

        MaxDivisors = Divisors

        AntiPrimeCount = AntiPrimeCount + 1

    END IF

WEND



PRINT: PRINT

tmp = "Execution Time in secs:##.###"

PRINT USING tmp; TIMER(0.001) - t



END



'FUNCTIONS AND SUBROUTINES ----------------------

FUNCTION DivisorCount (v)

    DIM AS LONG total, count, n, p

    total = 1

    n = v

    WHILE n MOD 2 = 0

        total = total + 1

        n = n \ 2

    WEND

    p = 3

    WHILE (p * p) <= n

        count = 1

        WHILE n MOD p = 0

            count = count + 1

            n = n \ p

        WEND

        p = p + 2

        total = total * count

    WEND

    IF n > 1 THEN total = total * 2

    DivisorCount = total

END FUNCTION



'END OF PROGRAM  --------------------------------

(07-06-2023, 07:16 PM)bplus Wrote: I don't know, can you find a formula? but your thing looks pretty fast! Have you looked at Rosetta Code this looks like a classic task for them.

Welcome to the forum!

Yes RC has it: https://rosettacode.org/wiki/Anti-primes#FreeBASIC
FreeBasic is usually a good one to compare with.

(07-06-2023, 07:54 PM)mnrvovrfc Wrote: Welcome to the forums.

I have never understood this need for speed, and even less, the desire to make the executable smaller. Because usually it comes from people needing to compare one thing to the other. Just use it, dude, if it's easy enough and convenient.

That comment wasn't aimed at the OP nor at anybody else in particular.

The program that I wrote to try to create prime palindromes out of 19-digit _INTEGER64, had performance that satisfied me. It had to search through an input file for possible candidates. For each candidate, it had to calculate if it were prime or not. I wasn't expecting the program to blaze through things with a lowly dual-core CPU and only 4GB RAM. The thing is I don't have time nor patience to "do" C++ to see if it could run faster and perhaps gobble up more RAM.

(07-06-2023, 11:38 PM)bplus Wrote: I am not seeing anything to improve speed, looks just fine to me. I think a slight advantage with calculations when all the numbers are of the same type and as I recall no advantage using Integers over Long because of 64 bit math. I tried everything Long and got about same time with 3 trials each way.

$checking:off

(07-07-2023, 11:50 AM)Jack Wrote: @Space_Ghost
put this at the top of your program

Code: (Select All)

$checking:off

you may gain a second or two in performance