+- QB64 Phoenix Edition (https://staging.qb64phoenix.com)
+-- Forum: QB64 Rising (https://staging.qb64phoenix.com/forumdisplay.php?fid=1)
+--- Forum: Prolific Programmers (https://staging.qb64phoenix.com/forumdisplay.php?fid=26)
+---- Forum: TheBOB (https://staging.qb64phoenix.com/forumdisplay.php?fid=27)
+---- Thread: Halloween Screen Saver - Happy Halloween! (/showthread.php?tid=216)
Halloween Screen Saver - Happy Halloween! - Pete - 04-26-2022
Halloween.bas by Bob Seguin
![[Image: Screenshot-640.png]](https://i.ibb.co/mcncz2j/Screenshot-640.png)
Description: Halloween screen saver with flickering jack-o-lantern.
Code: (Select All)
_TITLE "Halloween.bas by Bob Seguin"
SCREEN 12
_FULLSCREEN
OUT &H3C8, 1: OUT &H3C9, 40: OUT &H3C9, 12: OUT &H3C9, 0
OUT &H3C8, 2: OUT &H3C9, 6: OUT &H3C9, 12: OUT &H3C9, 0
OUT &H3C8, 3: OUT &H3C9, 30: OUT &H3C9, 8: OUT &H3C9, 0
OUT &H3C8, 4: OUT &H3C9, 3: OUT &H3C9, 8: OUT &H3C9, 0
OUT &H3C8, 7: OUT &H3C9, 63: OUT &H3C9, 0: OUT &H3C9, 0
OUT &H3C8, 8: OUT &H3C9, 46: OUT &H3C9, 0: OUT &H3C9, 0
OUT &H3C8, 9: OUT &H3C9, 63: OUT &H3C9, 63: OUT &H3C9, 63
OUT &H3C8, 12: OUT &H3C9, 20: OUT &H3C9, 20: OUT &H3C9, 20
OUT &H3C8, 13: OUT &H3C9, 0: OUT &H3C9, 0: OUT &H3C9, 0
OUT &H3C8, 14: OUT &H3C9, 55: OUT &H3C9, 35: OUT &H3C9, 0
DATA 1,1.2,1.8,5
CIRCLE (320, 240), 100, 3, , , .9
PAINT (320, 240), 3
CIRCLE (320, 230), 90, 1, , , .9
PAINT (320, 230), 1
FOR Reps = 1 TO 4
READ Elipse
FOR E = Elipse TO Elipse + .1 STEP .01
CIRCLE (320, 240), 100, 3, , , E
NEXT E
NEXT Reps
FOR Radius = 38 TO 43
CIRCLE (320, 160), Radius, 3, , , .4
NEXT Radius
CIRCLE (320, 160), 40, 14, 3.3, 6, .4
CIRCLE (320, 240), 100, 5, , , .9
PAINT (0, 0), 5
CIRCLE (320, 240), 100, 0, , , .9
PAINT (0, 0), 0
FOR Radius = 12 TO 18
CIRCLE (320, 153), Radius, 2, , , .3
NEXT Radius
CIRCLE (320, 150), 12, 2, , , .6
PAINT STEP(0, 0), 2
CIRCLE (300, 143), 32, 2, 6, 1.1
CIRCLE (276, 143), 32, 2, 6, .6
DRAW "BM302,125 C2 M+15,-10 BD10 P2,2"
PAINT (320, 145), 2
CIRCLE (282, 143), 32, 4, 6, .73
CIRCLE (266, 156), 60, 4, .1, .68
CIRCLE (320, 150), 12, 4, 3.14159, 0, .2
DRAW "BM302,125 C4 M+15,-10 BD10"
CIRCLE (276, 143), 32, 4, 6, .6
PAINT STEP(35, 0), 4
'Face begins
CIRCLE (303, 316), 100, 14, 1.5, 2
CIRCLE (337, 316), 100, 14, 1.1, 1.64
PSET (310, 215), 14
DRAW "H30 M-20,+40 M+12,-4 M+14,-29 BL2 P14,14 BF12 P15,14"
PSET (330, 215), 14
DRAW "E30 M+20,+40 M-12,-4 M-14,-29 BR2 P14,14 BG12 P15,14"
PSET (320, 246), 14
DRAW "R20 H20 G20 R20 U nL19 nR19 BU2 P15,14"
CIRCLE (320, 170), 100, 14, 3.8, 4.1
CIRCLE (320, 170), 100, 14, 4.42, 5.01
CIRCLE (320, 170), 100, 14, 5.33, 5.62
CIRCLE (320, 220), 80, 14, 3.29, 4.5
CIRCLE (320, 220), 80, 14, 4.66, 6.15
PSET (260, 250), 14
DRAW "D10 F8 U13 M+10,+5 D12 M+12,+6 U12 BR60"
DRAW "D12 M+12,-6 U12 M+10,-5 D13 E8 U10"
PSET (300, 297), 14
DRAW "U14 R16 D16"
CIRCLE (320, 212), 80, 14, 3.42, 4.5
CIRCLE (320, 212), 80, 14, 4.66, 6
LINE (300, 280)-(316, 283), 14, BF
PAINT (320, 296), 14
PAINT (290, 292), 14
PAINT (300, 278), 15, 14
CIRCLE (100, 240), 32, 13
PAINT STEP(0, 0), 13
FOR x% = 58 TO 142
FOR y% = 198 TO 282
IF POINT(x%, y%) = 13 THEN
IF POINT(x% + 220, y%) = 15 THEN PSET (x% + 220, y%), 9
END IF
NEXT y%
NEXT x%
COLOR 13: LOCATE 1, 1: PRINT "HAPPY HALLOWEEN!"
xx = 64: yy = 360
FOR x% = 0 TO 300
FOR y% = 0 TO 16
IF POINT(x%, y%) = 13 THEN
IF y% > 6 THEN Colr = 8 ELSE Colr = 7
LINE (x% * 4 + xx, y% * 4 + yy)-(x% * 4 + xx + 3, y% * 4 + yy + 3), Colr, BF
END IF
NEXT y%
NEXT x%
FOR x% = 0 TO 639
IF POINT(x%, 368) <> 0 THEN PSET (x%, 368), 14
NEXT x%
LINE (5, 5)-(634, 474), 12, B
LINE (8, 8)-(631, 471), 12, B
LINE (50, 354)-(580, 420), 15, B
DO
FOR Reps = 1 TO 3
WAIT &H3DA, 8
WAIT &H3DA, 8, 8
NEXT Reps
Flicker = FIX(RND * 20)
OUT &H3C8, 14
OUT &H3C9, 40 + Flicker
OUT &H3C9, 25 + Flicker
OUT &H3C9, 10 + Flicker
OUT &H3C8, 15
OUT &H3C9, 43 + Flicker
OUT &H3C9, 38 + Flicker
OUT &H3C9, 20 + Flicker
LOOP WHILE INKEY$ = ""
SYSTEM