Extension of playable audio formats in QB64 (32 bit)

Code: (Select All)

'Author: RhoSigma



'***********************************

'*** Use the QB64 32-bit version ***

'*** the DLL is for 32 bits only ***

'***********************************



'--- declare the required (only) DLL routines, there are much more ---

DECLARE DYNAMIC LIBRARY "./libxmp"

    FUNCTION xmp_create_context%& ()

    SUB xmp_free_context (BYVAL xmp_context%&)

    FUNCTION xmp_load_module& (BYVAL xmp_context%&, path$)

    SUB xmp_release_module (BYVAL xmp_context%&)

    FUNCTION xmp_start_player& (BYVAL xmp_context%&, BYVAL rate&, BYVAL format&)

    FUNCTION xmp_play_buffer& (BYVAL xmp_context%&, BYVAL buffer%&, BYVAL size&, BYVAL loops&)

    SUB xmp_end_player (BYVAL xmp_context%&)

END DECLARE



'--- init player ---

ctx%& = xmp_create_context%&



xErr& = xmp_load_module&(ctx%&, "s.xm" + CHR$(0)) 'load music MOD/XM/S3M file (amiga MOD file format)

xErr& = xmp_start_player&(ctx%&, _SNDRATE, 0)



'--- get storage for sound data ---

DIM buf AS _MEM

bsz& = _SNDRATE * 5 * 2 * 2 'space for 5 seconds 16-bit stereo sound

buf = _MEMNEW(bsz&)



'--- init scroll text ---

txt$ = "The 'External Module Player (XMP)' library (http://xmp.sourceforge.net/) " +_

       "integrated into the QB64 parts system could greatly improve the sound " +_

       "abilities of QB64 by easily adding dozens of well known and even some " +_

       "obscure music tracker formats from various platforms ontop of the already " +_

       "existing sound functions. Hence it could bring back a couple of those " +_

       "formats, which got lost with the transition from SDL to OpenGL. --- --- "



'--- main loop ---

PRINT "Press any key to stop replay, or wait until end ..."

st! = TIMER





DO

    _LIMIT 7

    IF _SNDRAWLEN < .5 THEN GOSUB RefillSoundBuffer

    'do your stuff here (non-blocking, ie. no INPUT etc.)

    LOCATE 10, 10

    PRINT LEFT$(txt$, 60)

    txt$ = MID$(txt$, 2) + LEFT$(txt$, 1)

    '-----

    LOCATE 14, 24

    PRINT USING "Buffered sound: ##.##### seconds"; _SNDRAWLEN

    '-----

    ct! = TIMER

    min$ = RIGHT$("00" + LTRIM$(STR$(INT((ct! - st!) / 60))), 2)

    sec$ = RIGHT$("00" + LTRIM$(STR$(INT((ct! - st!) - (VAL(min$) * 60)))), 2)

    LOCATE 16, 24

    PRINT USING "  Elapsed time:  &:& (mm:ss)"; min$; sec$

LOOP UNTIL xErr& 'WHILE NOT xErr& AND _KEYHIT = 0

_SNDRAWDONE



'--- free storage ---

_MEMFREE buf



'--- free player ---

xmp_end_player ctx%&

xmp_release_module ctx%&

xmp_free_context ctx%&



'--- wait until _SNDRAW is done ---

LOCATE 1, 1: COLOR 28

PRINT "Replay stopped or reached end, emptying sound buffer ...": COLOR 12

DO

    _LIMIT 7

    LOCATE 10, 10

    PRINT LEFT$(txt$, 60)

    txt$ = MID$(txt$, 2) + LEFT$(txt$, 1)

    remain# = _SNDRAWLEN

    '-----

    LOCATE 14, 24

    PRINT USING "Buffered sound: ##.##### seconds"; remain#

    '-----

    ct! = TIMER

    min$ = RIGHT$("00" + LTRIM$(STR$(INT((ct! - st!) / 60))), 2)

    sec$ = RIGHT$("00" + LTRIM$(STR$(INT((ct! - st!) - (VAL(min$) * 60)))), 2)

    LOCATE 16, 24

    PRINT USING "  Elapsed time:  &:& (mm:ss)"; min$; sec$

LOOP UNTIL remain# = 0



'--- guess what ---

END



'--- get next portion of sound and send to _SNDRAW ---

RefillSoundBuffer:

'To avoid sound garbage at the end, we first clear the

'buffer, just in case the final portion doesn't fill the

'entire buffer anymore.

_MEMFILL buf, buf.OFFSET, bsz&, 0 AS _BYTE

'-----

xErr& = xmp_play_buffer&(ctx%&, buf.OFFSET, bsz&, 1)

'PRINT bsz&, xErr&



FOR i& = 0 TO (bsz&) - 2 STEP 4

    leftSample& = _MEMGET(buf, buf.OFFSET + i&, INTEGER)

    rigtSample& = _MEMGET(buf, buf.OFFSET + i& + 2, INTEGER)

    _SNDRAW leftSample& / 32768#, rigtSample& / 32768#

NEXT i&



RETURN

Code: (Select All)

'must be compiled in 32bit IDE

DECLARE DYNAMIC LIBRARY "./imfLib"

    SUB InitIMFPlayer

    SUB StartIMFMusic (BYVAL pointer AS _OFFSET, BYVAL size AS _OFFSET)

    SUB ShutdownIMFPlayer ()

    SUB SetIMFEndedEvent (hwnd, UWM_MUSICENDED)

    '//           where hwnd is the window to get your user defined

    '//           message UWM_MUSICENDED (i.e. #define UWM_MUSICENDED (WM_APP + 1)).

    '//           There you should restart the song by just calling

    '//           StartIMFMusic with the same pointer again, or load

    '//           another song and start this.

END DECLARE









file$ = "test.imf"

T = 0

ff = FREEFILE

OPEN file$ FOR BINARY AS ff

size = LOF(ff) - T



REDIM NewSound AS _MEM

NewSound = _MEMNEW(size)

s$ = SPACE$(size)

REM SEEK ff, T

GET #ff, , s$

_MEMPUT NewSound, NewSound.OFFSET, s$

s$ = ""

CLOSE #ff



InitIMFPlayer

StartIMFMusic NewSound.OFFSET, NewSound.SIZE

SetIMFEndedEvent _WINDOWHANDLE, 5

DO

    LOCATE 1

    PRINT "Press any key to end. For listening set your audio to stereo and disable some dolby software!"



LOOP UNTIL _KEYHIT = 32



ShutdownIMFPlayer

_MEMFREE NewSound

END