Anyone know how frostbite thresholds are calculated?

[SMcNeill]

If you want a Celius and KpH windchill chart, take a look at this one:

Code: (Select All)

SCREEN _NEWIMAGE(800, 600, 32)
$COLOR:32
PRINT "  ";
count = 1
FOR temp = 40 TO -45 STEP -5
    LOCATE , 4 * count
    PRINT temp;
    count = count + 1
NEXT
PRINT


FOR windspeed = 5 TO 60 STEP 5
    COLOR White, Black
    PRINT windspeed;
    COLOR Black, SkyBlue
    count = 1
    FOR temp = 40 TO -45 STEP -5
        wc& = WindChill(temp, windspeed)
        LOCATE , 4 * count
        count = count + 1
        SELECT CASE wc&
            CASE IS > -18: COLOR Black, LightBlue
            CASE IS > -32: COLOR White, SkyBlue
            CASE IS > -48: COLOR White, Blue
            CASE ELSE: COLOR White, Purple
        END SELECT

        PRINT wc&; " ";
    NEXT
    PRINT
NEXT

COLOR White, Black

PRINT: PRINT
PRINT "Celius and Windspeed in KpH"
PRINT "  ";
count = 1
FOR temp = 40 TO -45 STEP -5
    LOCATE , 4 * count
    PRINT F2C(temp);
    count = count + 1
NEXT
PRINT


FOR windspeed = 5 TO 60 STEP 5
    COLOR White, Black
    PRINT M2K(windspeed);
    COLOR Black, SkyBlue
    count = 1
    FOR temp = 40 TO -45 STEP -5
        wc& = F2C(WindChill(temp, windspeed))
        LOCATE , 4 * count
        count = count + 1
        SELECT CASE wc&
            CASE IS > -18: COLOR Black, LightBlue
            CASE IS > -32: COLOR White, SkyBlue
            CASE IS > -48: COLOR White, Blue
            CASE ELSE: COLOR White, Purple
        END SELECT
        PRINT wc&; " ";
    NEXT
    PRINT
NEXT


FUNCTION WindChill& (temp AS _FLOAT, windspeed AS _FLOAT)
    WindChill = 35.74 + 0.6215 * temp - 35.75 * windspeed ^ 0.16 + 0.427 * temp * windspeed ^ 0.16
END FUNCTION

FUNCTION F2C& (temp)
    F2C = (temp - 32) * 5 / 9
END FUNCTION

FUNCTION M2K (mile)
    M2K = 1.609344 * mile
END FUNCTION

First chart is "Americanized" while the second is "Europeanized".